class ParticleList extends ArrayList
{
  void tick()
  {
    Iterator i = iterator();
    while(i.hasNext())
    {
      Particle p = (Particle) i.next();
      p.tick();
      if(p.life <= 0) i.remove();
    }
  }
  void draw()
  {
    Iterator i = iterator();
    while(i.hasNext())
    {
      Particle p = (Particle) i.next();
      p.draw();
    }
  }
}

boolean inRadius(PVector a, PVector b, float rad)
{
  return rad*rad > (a.x - b.x)*(a.x - b.x) + (a.y - b.y) * (a.y - b.y);// + (a.z - b.z) * (a.z - b.z);
}

abstract class Particle
{
  PVector pos;
  PVector vel;
  PVector accel;
  int life;
  int maxlife;
  Particle(PVector p, PVector v, int lifetime)
  {
    this(p, v, new PVector(0, 0), lifetime);
  }
  Particle(PVector p, PVector v, PVector a, int lifetime)
  {
    accel = new PVector(a.x, a.y);
    pos = new PVector(p.x, p.y);
    vel = new PVector(v.x, v.y);
    life = maxlife = lifetime;
  }
  void tick()
  {
    vel.add(accel);
    pos.add(vel);
    life--;
  }
  abstract void draw();
}

PVector proj(PVector src, PVector dest)
{
  return PVector.mult(dest, src.dot(dest)/dest.dot(dest));
}

void regPoly(float x, float y, float r, int sides, float rot)
{
  beginShape();
  for(int i = 0; i < sides; i++)
  {
    float segAngle = TWO_PI/sides;
    vertex(cos(i*segAngle + rot) * r + x,  sin(i*segAngle + rot) * r + y);
  }
  endShape(CLOSE);
}

void regStar(float x, float y, float r, int sides, float rot)
{
  beginShape();
  for(int i = 0; i < sides; i++)
  {
    float segAngle = TWO_PI/sides * 2;
    vertex(cos(i*segAngle + rot) * r + x,  sin(i*segAngle + rot) * r + y);
  }
  endShape(CLOSE);
}

PVector randomVector(float magn)
{
  float angle = random(TWO_PI);
  return new PVector(cos(angle)*magn, sin(angle)*magn);
}